Recently a reader asked us how to add "Open File Location" option in Windows XP? Actually Windows Vista and 7 provide this option in file context menu. Whenever you right-click on a shortcut, you get "Open File Location" option which leads you to the folder containing the original file.
You can get this useful option in Windows XP using a very simple registry hack. Simply download following ZIP file, extract it and run the "Add Open File Location Option in Windows XP.Reg" file to add this option. There is also an Undo file in case you want to remove the option:
Posted by: Vishal Gupta | Categories: Windows XP
Bonnie West
'OpenFileLocation.vbs by Bonnie West
'Put this in your WINDOWS folder
Option Explicit
Const OFL = "OpenFileLocation"
Const sKEY = "HKCU\Software\Classes\lnkfile\shell\OpenFileLocation\"
Const sVALUE = "Open &file location"
Const sCMD = "wscript.exe %WINDIR%\OpenFileLocation.vbs ""%1"""
Dim WshShell
Set WshShell = WScript.CreateObject("WScript.Shell")
If WScript.Arguments.Count Then
OpenFileLocation
Else
InstallUninstallOFL
End If
Set WshShell = Nothing
Sub OpenFileLocation
Dim FSO, sTarget
sTarget = WshShell.CreateShortcut(WScript.Arguments(0)).TargetPath
Set FSO = WScript.CreateObject("Scripting.FileSystemObject")
If FSO.FileExists(sTarget) Or FSO.FolderExists(sTarget) Then
WshShell.Run "explorer.exe /select,""" & sTarget & """"
Else
MsgBox "Could not find:" & vbCrLf & vbCrLf & _
"""" & sTarget & """", vbExclamation, OFL
End If
Set FSO = Nothing
End Sub
Sub InstallUninstallOFL
Dim sPrompt, iButtons
sPrompt = "Do you want to add the ""Open file location"" context menu " & _
"option to shortcut files?" & vbCrLf & "(Select NO to remove)"
iButtons = vbYesNoCancel + vbQuestion + vbDefaultButton3
iButtons = MsgBox(sPrompt, iButtons, "Install " & OFL & ".vbs")
On Error Resume Next
Select Case iButtons
Case vbYes
WshShell.RegWrite sKEY, sVALUE, "REG_SZ"
WshShell.RegWrite sKEY & "command\", sCMD, "REG_EXPAND_SZ"
Case vbNo
WshShell.RegDelete sKEY & "command\"
WshShell.RegDelete sKEY
End Select
If Err Then
MsgBox Err.Description, vbCritical, Err.Source
Else
Select Case iButtons
Case vbYes: MsgBox "Installed successfully!", vbInformation, OFL
Case vbNo: MsgBox "Uninstalled successfully!", vbInformation, OFL
End Select
End If
End Sub
Dinesh
Thanks..it worked for me..
Rayo
Useless piece of utility. Instead of bringing you to the actual folder where the application, url, exe, it brings you to the folder of its shortcut. This is not Finding Location of File or what we call Find Target of File. I don't know what this is, but typically useless.